이 7가지 조건부 서식 수식은 엑셀을 자동 알림 시스템으로 바꿉니다

엑셀의 기본 하이라이트는 단순한 경우에는 유용하지만, 데이터가 복잡해지면 금세 한계를 드러냅니다. 수식 기반 조건부 서식은 정적인 스프레드시트를 데이터가 변경될 때 즉시 반응하는 자동 경고 시스템으로 바꿉니다. 이는 셀 안에 직접 ‘이것이면 저것’ 논리를 구축하는 간단한 방법입니다.

수식 기반 서식 작업 흐름을 마스터하세요

엑셀 표로 설정하고 잊으세요

이 가이드의 모든 조건부 서식 규칙은 동일한 핵심 단계를 사용하므로, 한 번 하면 천 번 한 것과 같습니다:

1. 데이터 셀을 선택하세요—왼쪽 상단 셀에서 시작하고 헤더 행은 제외합니다.
2. 홈 > 조건부 서식 > 새 규칙 으로 이동합니다.
3. 서식을 지정할 셀 결정에 수식 사용를 선택합니다.
4. 수식 입력란에 수식을 입력하세요.
5. 형식을 클릭하여 스타일을 선택하세요.
6. 확인을 클릭하세요.

최상의 결과를 얻으려면 규칙을 적용하기 전에 데이터를 Excel 표(Ctrl+T)로 형식화하세요. 조건부 서식은 표준 셀 참조를 사용하지만, 표는 새 행이 추가될 때 서식을 자동으로 확장합니다.

단일 셀 상태를 기준으로 한 행의 모든 열을 강조 표시합니다

깨끗한 수평 알림 만들기

엑셀의 내장 조건부 서식 규칙은 일반적으로 목표에 맞는 특정 셀만 색칠합니다. 효과가 있긴 하지만, 시트가 읽기 어려운 엉망진창 체커보드처럼 보이게 만드는 경우가 많습니다. 깔끔하고 읽기 쉬운 레이아웃을 원한다면, 단일 상태가 변경될 때 전체 행을 밝히도록 맞춤 수식을 사용하는 것이 더 낫습니다.

시나리오: E열에서 상태를 '완료'로 변경하는 순간 전체 테이블 행이 노란색으로 바뀌기를 원합니다.

이를 위해 전체 데이터 범위를 선택하고 다음 수식을 사용하여 조건부 서식 규칙을 만드세요:

=$E2="Complete"

달러 기호는 규칙을 E열에 고정시키는 반면, 행 참조는 상대적으로 유지되어 각 행이 독립적으로 평가됩니다.

두 열 간의 값을 비교하여 불일치를 식별합니다

예산 초과를 자동으로 추적

표준 형식 규칙은 고정된 숫자에 가장 잘 작동하지만, 실제 생활은 그렇게 단순하지 않은 경우가 많습니다. 프로젝트 추적기에서는 각 항목마다 예산이 다를 수 있으므로, 지출을 초과했는지 수동으로 확인하는 것은 필요 없는 골칫거리입니다.

상황: 실제 지출(열 D)이 예산(열 C)을 초과하는 모든 프로젝트를 분홍색으로 표시해야 합니다.

필요한 공식은 다음과 같습니다:

=$D2>$C2

이 수식은 각 행을 직접 비교하여 실제 지출이 예산을 초과하는 경우를 표시합니다. 나중에 어느 한 쪽 값이 변경되면 서식이 자동으로 업데이트됩니다.

데이터 범위 전반에서 누락되었거나 불완전한 정보를 식별합니다

전체 데이터 무결성 유지

우리 모두 그런 경험이 있습니다—보고서를 보고 있는데 누군가 중요한 담당자 이름이나 마감일을 기입하는 것을 잊었다는 것을 깨닫는 경우죠. 빈 셀은 수식을 망가뜨리기 때문에, 직접 찾아다니기보다는 엑셀에게 찾아보도록 맡기세요.

시나리오: 누락된 정보가 있는 프로젝트 행을 강조 표시하고 싶습니다.

이것이 마법의 공식입니다:

=COUNTBLANK($A2:$F2)>0

COUNTBLANK 함수는 행 범위 내 빈 셀의 수를 계산합니다. 결과가 0보다 크면 규칙이 실행됩니다.

여러 조건을 하나의 규칙으로 결합하다

시각적 잡음을 걸러내다

때로는 하나의 조건만으로는 충분하지 않을 수 있습니다. 진행 중이며 지출 한도를 초과하는 프로젝트에만 관심이 있을 수 있습니다.

상황: 진행 중인 열(E)에 있으며 그리고 5,000달러(D열) 이상을 사용한 행만 회색으로 강조 표시하고 싶습니다.

이것이 조건부 서식 규칙에서 AND 함수가 사용되는 곳입니다:

=AND($E2="In Progress",$D2>5000)

이렇게 하면 두 조건이 동시에 참일 때만 규칙이 작동하여 시트의 시각적 혼란을 줄이는 데 도움이 됩니다.

키워드를 검색하기 위해 전용 참조 셀을 사용하세요

실시간 검색 바 만들기

엑셀에는 내장 검색 도구가 있지만, 새로운 키워드를 찾을 때마다 메뉴로 돌아가는 것은 귀찮습니다. 훨씬 더 멋진 방법은 형식을 특정 셀에 연결하여 즉시 검색할 수 있게 하는 것입니다.

상황: 키워드("감사"와 같은)를 H2 셀에 입력하면 A열의 모든 일치하는 프로젝트 이름이 있는 행이 즉시 녹색으로 표시되기를 원합니다.

이번에는 조건부 서식 수식에서 ISNUMBER와 SEARCH를 결합해야 합니다:

=ISNUMBER(SEARCH($H$2,$A2))

SEARCH 함수(대소문자 구분 없음)는 A2의 텍스트 내에서 H2의 키워드를 검색합니다. 일치 항목을 찾으면 숫자를 반환하고, 그렇지 않으면 오류를 반환합니다. ISNUMBER는 조건부 서식을 위해 해당 결과를 TRUE 또는 FALSE로 변환합니다.

이제 H2 셀에 다른 키워드를 입력하면 서식이 그에 따라 업데이트되는 것을 확인할 수 있습니다.

현재 날짜를 기준으로 반복 알림 계산

실시간으로 마감일을 추적하세요

정적인 날짜 규칙은 빠르게 구식이 됩니다. 마감일을 유용하게 유지하려면 자동으로 업데이트되고 실제로 관심 있는 시간 범위만 강조하는 규칙이 필요합니다.

시나리오: 앞으로 7일 이내에 F열에 마감일이 있는 프로젝트를 오렌지색으로 강조 표시하고 싶습니다—기한이 지난 항목은 표시하지 않습니다. 이 예제에서는 오늘 날짜를 2026-05-11로 가정합니다.

이것을 제대로 하려면 단일 비교가 아니라 날짜 범위가 필요합니다. 조건부 서식 규칙에 이 수식을 사용하세요:

=AND($F2>=TODAY(),$F2<=TODAY()+7)

이것은 동시에 두 가지 조건을 확인합니다:

• 날짜가 과거가 아닙니다 ($F2>=TODAY())
• 날짜가 다음 7일 내에 있습니다 ($F2<=TODAY()+7)

둘 다 참일 때만 서식이 적용됩니다.

이는 =$F 2<=TODAY()+7과 같은 단일 조건 규칙도 연체된 작업도 포함하기 때문에 중요합니다. 하한선을 추가하면 하이라이트가 포괄적인 필터가 아니라 적절한 롤링 '예정 마감' 창처럼 작동하도록 할 수 있습니다.

여러 데이터 필드를 매칭하여 복잡한 중복 항목 찾기

숨겨진 중복 항목 발견

간단한 중복 규칙은 실제 오류가 아닌 것들도 자주 표시합니다. 동일한 항목 이름이 여러 번 정당하게 나타날 수 있지만, 부차적인 세부 사항이 정확히 동일하게 두 번 나타난다면, 아마도 사무상의 실수를 발견한 것입니다. 두 개 이상의 열을 동시에 확인하여 이러한 관계형 중복을 잡을 수 있습니다.

상황: A열과 B열의 값이 모두 목록의 이전 항목과 일치하는 경우에만 해당 행에 플래그를 지정하고 싶습니다.

공식은 다음과 같습니다:

=COUNTIFS($A$2:$A2,$A2,$B$2:$B2,$B2)>1

범위 $A$2:$A2는 시트를 아래로 이동할 때 확장되므로, 엑셀은 현재 행 위의 행만 평가합니다. 이것이 한 번에 모두가 아니라 점진적으로 중복을 감지할 수 있게 하는 이유입니다.

시각적 조정에서 스마트 로직으로의 전환

조건부 서식 수식은 Excel을 데이터 변경에 따라 업데이트되는 반응형 시스템으로 바꿉니다. 누락된 값을 표시하든, 예산을 추적하든, 불일치를 찾든, 이러한 규칙은 스프레드시트를 명확하고 자동화된 상태로 유지합니다. 알림이 설정되면, 데이터를 감사하고 정리하기 위해 Excel의 '이동 옵션' 도구를 사용하는 방법을 배우는 것이 자연스러운 다음 단계입니다.