마이크로소프트 엑셀에서 FIND 함수 사용 방법

엑셀의 대부분의 함수와 도구는 대문자와 소문자의 차이를 무시하며, 이는 대소문자를 구분하는 ID가 작업 흐름을 방해할 때까지는 문제가 되지 않습니다. FIND 함수는 데이터의 엄격한 문지기 역할을 하며, 대소문자를 제안이 아니라 중요한 데이터 요소로 취급합니다.

엑셀에서 FIND 함수가 작동하는 방식

대소문자를 구분하는 정밀도를 위한 구문을 숙달하세요

FIND 함수는 특정 문자나 텍스트 문자열을 찾아 그 숫자 위치를 반환합니다. SEARCH 함수와 달리, 이 도구는 대소문자를 엄격히 구분합니다.

세 개의 인수를 사용합니다:

=FIND(find_text, within_text, [start_num])

위치 :

find_text (필수)은 찾으려는 텍스트(“쌍따옴표” 안에 입력)를 의미합니다. FIND 함수는 와일드카드를 지원하지 않는다는 점에 유의하세요.
within_text (필수) 는 분석하려는 데이터가 들어 있는 셀 또는 문자열입니다.
start_num (선택 사항)은 검색이 시작되는 문자 위치입니다.

FIND가 정확한 대소문자 구분 일치를 찾을 수 없으면 #VALUE! 오류를 반환합니다.

이 가이드를 읽으면서 따라가려면 예제에서 사용된 Excel 워크북의 무료 사본을 다운로드하세요. 링크를 클릭하면 화면 오른쪽 상단에서 다운로드 버튼을 찾을 수 있으며, 파일을 열면 아래 각 사용 사례를 별도의 워크시트 탭에서 확인할 수 있습니다.

사용 사례 1: 대소문자를 구분하여 일치하는 티어 ID 표시

사람 계정과 자동 계정 구분하기

많은 엑셀 스프레드시트에서, 대소문자 차이만이 두 데이터 범주를 구분하는 유일한 요소인 경우가 있습니다. 예를 들어, 대문자 "A"는 인간 직원 계정을 나타낼 수 있는 반면, 소문자 "a"는 자동화 시스템 계정을 나타낼 수 있습니다.

시나리오: T_Staff 테이블에서 ID에 텍스트 어디에나 대문자 "A"가 포함된 행은 "Human"으로 표시하고, 나머지는 모두 "System"으로 표시해야 합니다.

셀 E2에 이 수식을 입력하고 Enter를 누르세요:

=IF(ISNUMBER(FIND("A", [@ID])), "Human", "System")

작동 방식은 다음과 같습니다:

FIND("A", [@ID])는 대문자 "A"만 찾습니다. 소문자 "a"를 찾으면 오류를 반환합니다.
ISNUMBER(...)는 결과를 확인합니다. 만약 숫자("A"의 위치)를 보면 TRUE를 반환합니다. 오류가 나타나면 FALSE를 반환합니다.
IF(...)는 TRUE/FALSE 결과를 기반으로 최종 레이블을 제공합니다.

사용 사례 2: "Pro"와 "pro"가 포함된 행 강조

조건부 서식에 대소문자 구분 규칙 적용

Excel에서 특정 키워드가 나타날 때마다 전체 행의 색을 변경하려면 FIND를 사용할 수 있습니다.

시나리오: T_Inventory에서 상태에 텍스트 문자열 "Pro"가 어디에든 포함된 행을 연한 초록색으로 표시하고 싶습니다.

다음과 같이 하세요:

테이블을 선택하세요(헤더 제외), A2 셀에서 시작합니다.
홈 > 조건부 서식 > 새 규칙 으로 이동합니다.
클릭 수식을 사용하여 서식을 지정할 셀 결정.
채우기 색상을 연두색으로 설정하려면 서식을 클릭하세요.
수식 필드에 다음을 입력한 후, 확인을 클릭하세요:

=ISNUMBER(FIND("Pro", $C2))

여기에서 구조화된 표 참조(예: [@Status])를 사용하지 않은 것을 눈치채실 수도 있습니다. 이는 Excel의 조건부 서식이 표준 셀 참조를 필요로 하기 때문입니다. 하지만 테이블에 더 많은 행을 추가하더라도 이를 업데이트할 필요는 없습니다—Excel이 이 규칙을 자동으로 확장할 만큼 '스마트'하기 때문입니다.

FIND는 대소문자를 구분하기 때문에 소문자 "pro" 행은 무시합니다. 달러 기호($C2)는 검색을 Status 열로 고정하면서도 형식을 전체 행에 적용할 수 있게 합니다.

사용 사례 3: 위치 논리를 사용한 데이터 검증

복잡한 규칙을 위한 문자들의 정확한 좌표를 찾으세요

엑셀의 FIND 함수는 줄자처럼 사용할 수 있습니다. 이 함수는 숫자 좌표(문자 위치)를 반환하기 때문에, 셀의 특정 위치에 문자가 나타날 때만 동작을 실행할 수 있습니다.

시나리오: T_ProductCodes 테이블의 'Legacy' 코드는 처음 세 글자 안에 대문자 'H'를 포함해야 합니다. 그 외의 모든 시나리오(예: 'H'가 나중에 나오거나 전혀 없는 경우)에서는 항목이 'Standard'로 분류됩니다.

셀 D2의 수식은 다음과 같습니다:

=IF(ISNUMBER(FIND("H", LEFT([@Code], 3))), "Legacy", "Standard")

이 예제에서는:

LEFT([@Code], 3)는 코드의 처음 세 문자를 잘라냅니다(예: "H-9", "1H-", "77H" 등).
FIND("H",...) 은 그 작은 세 글자 범위 내에서 대문자 "H"만 찾습니다. 만약 있으면 첫 번째 발생 위치(1, 2 또는 3)를 반환합니다. 없으면 오류를 반환합니다.
ISNUMBER(...)은 FIND가 숫자를 반환하는지 확인합니다. 그렇다면 TRUE를 반환하고, 그렇지 않으면 FALSE를 반환합니다.
IF(...)는 ISNUMBER가 TRUE를 반환하면 "Legacy"를, FALSE를 반환하면 "Standard"를 반환합니다.

만약 "H"가 위치 1, 2 또는 3에 있으면, "Legacy"를 반환합니다. 위치 4 이후이거나 아예 없으면, "Standard"를 반환합니다. 일반적인 검색 대신 FIND를 사용하면, 우연히 소문자가 잘못된 상태를 유발하는 것을 방지할 수 있습니다.

MAKEARRAY와 SORTBY 같은 현대적인 엑셀 함수가 종종 주목을 받습니다. 하지만 FIND와 같은 기존 함수들은 여전히 고급 데이터 관리를 위한 핵심입니다. 숙련된 사용자에게 이러한 함수들은 단순히 '오래된' 함수가 아니라, 현대의 '스마트' 도구들이 종종 부족한 논리와 투명성을 제공하는 일상적인 필수 도구입니다. 이러한 안정적인 기반에 의존함으로써, 작업이 전문적이고 정확하며 모든 사람이 접근할 수 있도록 보장할 수 있습니다.